0. Código

>	restart; with(plots): with(geometry):

Warning, the name changecoords has been redefined

>

sbl := 'axes = none,   scaling = constrained,        thickness = 3, color = COLOR(RGB, .5,.4,.8)': sgy := 'axes = none,   scaling = constrained,        thickness = 3, color = COLOR(RGB, .5,.5,.6)': sbe := 'axes = none,   scaling = constrained,        thickness = 3, color = COLOR(RGB, .8,.7,.5)': sor := 'axes = none,   scaling = constrained,        thickness = 3, color = COLOR(RGB, .9,.7,.1)': sgn := 'axes = none,   scaling = constrained,        thickness = 3, color = COLOR(RGB, .4,.7,.4)':

>	cbl := 'color = COLOR(RGB, .5,.4,.8)': cgy := 'color = COLOR(RGB, .5,.5,.6)': cbe := 'color = COLOR(RGB, .8,.7,.5)': cor := 'color = COLOR(RGB, .9,.7,.1)': cyl := 'color = COLOR(RGB, .9,.8,.1)': cgn := 'color = COLOR(RGB, .5,.8,.5)':

>	scanft := 'scaling = constrained, axes = none': scanft := 'filled = true, axes = none, scaling = constrained': scant2 := 'thickness = 2, axes = none, scaling = constrained':

>

>	point(o,0,0); circle( UC ,[o,1]):

>	RegPolyPlot  :=  proc( N )   local k, n, ngon, c;   ngon := n -> [seq([ cos(2*Pi*i/n), sin(2*Pi*i/n) ], i = 1..n)]:     c := n -> COLOR(RGB, .2+n/(2*N), .2+n/(2*N), .5);   display([ seq( polygonplot(ngon(n), color=c(n)), n = 3..N)],            scaling = constrained, axes = none); end proc:

  1. Polígonos

Um polígono é qualquer forma simples e fechada formados com segmentos de linha.

>	plot( [ [0,0],[2,0],[3,5],[1,4],[-2,1],[0,0]], sgy );

Alguns polígonos familiares incluem triângulos ...

>	display( plot( [ [3,0],[7,0],[5,6],[3,0]], sgy ),          plot( [ [-7,5],[-5,7],[-2,5],[-7,5]], sbe ),          plot( [ [-5,3],[3,3],[3,6],[-5,3]], sor ),                  plot( [ [-6,0],[-1,0],[-8,2],[-6,0]], sgn ) );

Quadrados e retângulos ....

>	display( plot( [ [3,0],[7,0],[7,6],[3,6],[3,0]], sgy ),          plot( [ [-5,1],[5,1],[5,3],[-5,3],[-5,1]], sgn ),          plot( [ [2,2],[4,2],[4,4],[2,4],[2,2]], sor ),          plot( [ [-7,5],[-7,2],[-2,2],[-2,5],[-7,5]], sbe )           );

Mais existem mais!

  2. Polígonos Regulares

Polígonos regulares são polígonos onde todos os lados são iguais e todos os ângulos interiores são iguais. Um polígono regular de cinco lados é chamado pentágono.

>	RegularPolygon( RegPoly,5,o,1): display( draw(RegPoly, scanft, cbl ));

Todos os polígonos regulares se adaptam a círculos.

>	display( draw(UC, scant2, cbe), draw(RegPoly, scanft, cbl ));

Aqui estão os detalhes desse pentágono.

>	detail(RegPoly);

Embora ele requeira alguma tradução, o que ele está dizendo é que o interior dos ângulos são estes vários graus.

>	(3/5)*Pi*(180/Pi);

Aqui estão alguns outros polígonos regulares. Você pode nomeá-los?

>	RegularPolygon( RegPoly ,3,o,1): display( draw(UC, scant2, cbe), draw(RegPoly, scanft, cgy )); detail(RegPoly);

>	RegularPolygon( RegPoly ,6,o,1): display( draw(UC, scant2, cbe), draw(RegPoly, scanft, cgn )); detail(RegPoly);

>	RegularPolygon( RegPoly ,8,o,1): display( draw(UC, scant2, color=black), draw(RegPoly, scanft, cor )); detail(RegPoly);

Aqui está um polígono regular de 17 lados, o qual tem alguma significância histórica (depois de encontrar a primeira construção de tal polígono, um jovem Gauss decidiu sua vida na matemática). Observe como ele está perto do círculo que o circunscreve.

>	RegularPolygon( RegPoly ,17,o,1): display( draw(UC, scant2, cbe), draw(RegPoly, scanft, cbl )); detail(RegPoly);

Se nós desenhássemos um número de polígonos regulares no mesmo diagrama nós podemos ver seu progresso. Aqui estão polígonos regulares com  3 a 10 lados, e xdepois  3 a 30 lados. Eles parecem preencher o círculo mais e mais.

>	RegPolyPlot(6);

>	RegPolyPlot(10);

>	RegPolyPlot(25);

  3. Ãngulos Interiores de Polígonos

Nós sabemos que a soma dos ângulos de um triângulo é 180 graus, e retângulo (ou qualquer polígono de quatro lados) é 360 graus.

>	n := 3; total_int_angles := 180;

>	n := 4; total_int_angles := 360;

Atualmente exisate uma fórmula :

>	total_interior := n -> 180*(n-2);

>	A := array( [seq( [ n, total_interior(n) ],   n = 2..10) ]): A[1,1] := `Number of sides`: A[1,2] := `Total Interior Angles`: print(A);

  4. Perímetro de Polígonos Regulares

Se existisse um polígono regular com 10 lados, e cada lado é 3 pés maior, o perímetro é fácil de calcular.

>

10*3;

 Por outro lado, se nós tivéssemos um polígono regular com 7 lados, e a distância do centro para qualquer dos vértices é 5 pés, qual é o perímetro? Esse é um problema que não pode ser respondido adequadamente até que você faça trigonometria, mas nós podemos usar o Maple para encontrar a resposta.

>	RegularPolygon( RegPoly ,7,o,5): display( draw(RegPoly, scanft, cgy )); detail(RegPoly);

>	P = evalf( 70*sin(Pi/7), 20);

  5. Área de Polígonos Regulares

Um polígono regular com  n lados pode ser dividido em n triângulos isósceles.

>	RegularPolygon( RegPoly ,7,o,1): point(A,[cos(2*Pi/7), sin(2*Pi/7)]); point(B,[cos(4*Pi/7), sin(4*Pi/7)]); point(C,[cos(3*Pi/7)*cos(Pi/7), sin(3*Pi/7)*cos(Pi/7)]); segment( rad1, [o, A]); segment( rad2, [o, B]); segment( h, [o, C]); segment( side, [A,B]);

>

display( draw(           [ UC(thickness=1,cbe), RegPoly(thickness=2,cgn),             rad1(color=red,thickness = 2),             rad2(color=gold, linestyle = 3),             h(thickness = 2, color = coral),             side(thickness = 3, color = green)           ]), axes=none, scaling=constrained        );

Você precisa de três partes de informação :
        1. n, o número de lados
        2. a altura de cada triângulo (a linha sólida amarelo/laranja no meio do triângulo)
        3. o comprimento de um lado do polígono.

Nós podemos obter isto através do comando detail ....
     
 

>	detail(RegPoly);

>	Area = 7*sin(Pi/7)*cos(Pi/7): evalf(%, 50);

  6. Estrelas

Outro tipo de polígono, que não é  "regular", mas é simétrico, é uma "estrela" - uma forma geralmente não estudada nos livros de geometria, mas certamente comum em ilustrações.

>	RegularStarPolygon( star,5/2,o,2): draw(star,filled = true, axes = none,scaling=constrained,color=orange);

Observe que uma estrela se adapta dentro de um polígono regular. Uma estrela de 5 lados se adapta dentro de um polígono de 5 lados. Assim, se você cortar os cinco pontos como vértices perto do centro, você verá que existe outro pentágono dentro da estrela também!

>	RegularPolygon( P2,5,o,2): RegularStarPolygon( star,5/2,o,2): draw( [P2(color=coral), star(color = red, filled = true)],           axes = none, scaling = constrained);

É claro que estrelas podem ser de outros tamanhos.

>	RegularStarPolygon( star,9/2,o,1): draw(star,          filled = true, axes = none, scaling = constrained, color=sienna );

>

>